home *** CD-ROM | disk | FTP | other *** search
/ Gigarom 1 / Gigarom Macintosh Archives (Quantum Leap)(CDRM1080320)(1993).iso / FILES / APP / M-R / PSpice.cpt / Example1.cir < prev    next >
Text File  |  1990-09-13  |  10KB  |  236 lines
  1. EXAMPLE1 - An Illustration of PSpice Capabilities
  2. * 
  3. * This circuit, a differential pair, shows many of the capabilities of PSpice.
  4. * It creates a large amount of output for such a small circuit.  Normally,
  5. * only a few kinds of analysis, such as transient analysis, would be run.
  6. * 
  7. * This command sets options for the run.
  8. .OPT ACCT NOMOD NOPAGE RELTOL=.001
  9.  
  10. * Sets the width of the output to 80 columns.
  11. .WIDTH OUT=80
  12.  
  13. * Sets the temperature for the run to 35 degrees celsius.
  14. .TEMP 35
  15.  
  16. * This command does a DC sweep.  The voltage source VIN is swept from
  17. *   -0.125 volts to 0.125 volts in steps of 0.005 volts.  The non-linear
  18. *   device equations are used.
  19. .DC VIN -0.125 0.125 0.005
  20.  
  21. * There is no command to do a small-signal bias point calculation.  It
  22. *   is done automatically after the DC sweep is finished.  The non-linear
  23. *   device equations are used to find the bias point.  Then, the linearized,
  24. *   small-signal equivalent circuit at the bias point is saved for the .TF,
  25. *   .SENS, .AC, and .NOISE analysis.  This command prints out the small-
  26. *   signal parameters for each device.
  27. .OP
  28.  
  29. * This command does a small-signal transfer function calculation assuming
  30. *   VIN is the input and V(5), the voltage at node 5, is the output.
  31. .TF V(5) VIN
  32.  
  33. * This does an AC analysis.  The real and imaginary response of the circuit
  34. *   is calculated as the inputs are swept from 100 kilohertz to 10 gigahertz
  35. *   by decades with 10 points per decade.  The only AC input this circuit has
  36. *   is VIN.  This is a linear analysis.
  37. .AC DEC 10 100KHZ 10GHZ
  38.  
  39. * This command does noise calculations during the AC analysis.  Each
  40. *   device's noise contribution is calculated and propogated to node 5.
  41. *   All the contributions are rms-summed at node 5.  Besides the total
  42. *   output noise printout done for every frequency, a detailed table of
  43. *   each device's contribution is done every 30'th frequency.
  44. .NOISE V(5) VIN 30
  45.  
  46. * This command does a transient analysis.  It first re-calculates the
  47. *   circuit's bias point, then calculates the circuit's time response
  48. *   from 0 nanoseconds to 250 nanoseconds using the full, non-linear device
  49. *   equations, including non-linear capacitances.  PSpice uses a variable
  50. *   time step for the calculations, but this command causes the results
  51. *   to be interpolated onto a 5 nanosecond print interval.  Transient
  52. *   analysis is the most frequently used analysis in PSpice.
  53. .TRAN 20NS 1000NS
  54.  
  55. * This does a harmonic decomposition on the waveform V(5) calculated
  56. *   during transient analysis.  It calculates the magnitude and phase
  57. *   of the fundamental (5 megahertz) and the first eight harmonics.
  58. *   The graphics post-processor, Probe, goes further and contains
  59. *   a full FFT, allowing complete spectra to be displayed.
  60. .FOUR 5MEG V(5)
  61.  
  62. * This command does a Monte Carlo analysis of the circuit.  It runs
  63. *   the DC sweep 5 times using the tolerances in .MODEL statements
  64. *   and compares the waveform V(4,5) from each run against the nominal
  65. *   V(4,5).  It then lists a table of each run's deviation from the 
  66. *   nominal.  The Monte Carlo option can also do Worst Case and Sensitivity
  67. *   analysis.
  68. .MC 5 DC V(4,5) YMAX
  69.  
  70. * PSpice allows parameters to be defined and used in expressions
  71. *   throughout the circuit file.  Parameters may also be passed into
  72. *   subcircuits as arguments and used inside.  Here, we define a
  73. *   fudge factor for the supply voltages.
  74. .PARAM FACTOR=1.2
  75.  
  76. * The following statements describe the circuit to PSpice.  It is a
  77. *   simple differential pair, with +12 and -12 volts as the supplies.
  78.  
  79. * VIN is the input for this circuit.  It has an amplitude during AC analysis
  80. *   of 1 volt and a sine waveform during transient of .1 volt at 5 megahertz.
  81. VIN 100 0 AC 1 SIN(0 0.1 5MEG)
  82.  
  83. * The power supplies are + and - SUPPLY volts.  As mentioned above,
  84. *   expressions containing parameters can be used for values throughout
  85. *   the circuit file.  Expressions are enclosed by "{" and "}" and allow
  86. *   arithmetic expressions.
  87. VCC 101 0 DC {10*FACTOR}
  88. VEE 102 0 {-10*FACTOR}
  89.  
  90. * The transistors' nodes are in the order collector - base - emitter.
  91. *   All transistors must refer to a model (QNL in this case).
  92. Q1 4 2 6 QNL
  93. Q2 5 3 6 QNL
  94.  
  95. * Models for resistors are optional.  If used they can specify such things
  96. *   as scaling, temperature coefficients, and tolerances.
  97. RS1 100 2 1K 
  98. RS2 3 0 1K
  99. RC1 4 101 CRES 10K
  100. RC2 5 101 CRES 10K
  101. Q3 6 7 102 QNL
  102. Q4 7 7 102 QNL
  103. RBIAS 7 101 20K
  104. CLOAD 4 5 5PF
  105.  
  106. * This statement describes the CRES resistor by giving the values for
  107. *   the parameters.  Each type of model has its own set of parameters.
  108. *   All parameters have default values.  In CRES we have set the scaling
  109. *   factor to 1, the linear temperature coefficient to .02, and the
  110. *   quadratic temperature coefficient to .0045, and given each resistor
  111. *   a 5% tolerance on its value during Monte Carlo analysis.
  112. .MODEL CRES RES (R=1 DEV=5% TC1=.02 TC2=.0045)
  113.  
  114. * The bipolar transistor model is the Gummel-Poon model.  It uses the
  115. *   same equations as in the UC Berkeley Spice program.  There are
  116. *   actually 55 model parameters, but most of these are for second-order
  117. *   effects that are rarely used.  Most bipolar models for realistic
  118. *   circuits specify between 12 and 25 parameters and default the rest.
  119. *   Here, we have set the forward beta to 80, the base resistance to
  120. *   100 ohms, the collector-substrate capacitance to 2 picofarads, the
  121. *   forward transit time to 0.3 nanoseconds, the reverse transit time to
  122. *   6 nanoseconds, the base-emitter capacitance to 3 picofarads, the
  123. *   base-collector capacitance to 2 picofarads, and the forward Early
  124. *   voltage to 50 volts.  The capacitances are actually voltage dependent.
  125. *   These numbers are the zero-bias values.
  126. .MODEL QNL NPN (BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
  127. +   VA=50)
  128.  
  129. * The Analog Behavioral Modeling option allows one to define a transfer
  130. *   function by formula and/or by table.  Here, we implement an ideal
  131. *   comparator to convert the differential output across nodes 4 and 5 into
  132. *   a TTL output on node 10.  The voltage across 4 and 5 is multiplied by 1e5
  133. *   and that value is looked up in the table.  The table has an output of 0v
  134. *   for inputs < 0, 5v for inputs > 5, and output=input in between.
  135. *   So, the comparator has a gain of 100,000 and saturates at 0v and 5v.
  136. * Although not shown here, one can also define linear transfer functions
  137. *   by Laplace transform formulas or by frequency response tables.
  138. E1    10 0    TABLE {V(4,5)*1e5}    (0v,0v 5v,5v)
  139. RE1    10 0    1K
  140.  
  141. * The Digital Simulation option simulates digital components.  Instead
  142. *   of voltages and waveforms, it calculates 1's and 0's and propogation
  143. *   delays.  PSpice automatically creates interface components between
  144. *   analog and digital sections or circuitry.  Here, we drive a 74293,
  145. *   4-bit, ripple counter from the output of the comparator E1.
  146.  
  147. X1 10 QA 110 110 QA QB QC QD 74293
  148.  
  149. * This is a digital stimulus which resets the counter
  150. U2 STIM(1, 1) 110 STMIOMDL TIMESTEP = 10NS
  151. +   0nS, 1
  152. +  40nS, 0
  153.  
  154. * These commands provide print and plot output for selected voltages
  155. *   and currents.  The plots are the so-called "line printer" plots.
  156. *   That is, plots made out of characters.  To get real, high-resolution
  157. *   plots you need to use Probe; it is invoked by the .PROBE command.
  158. .PRINT DC V(4) V(5)
  159. .PLOT DC IC(Q2) 
  160. .PLOT AC VCM(Q2) VCP(Q2)
  161. .PLOT NOISE INOISE ONOISE 
  162. .PLOT TRAN V(4,5) V(10)    D(QA) D(QB)
  163. .PROBE
  164.  
  165. * We have included the full subcircuit and model definitions here in
  166. *   order to make the EXAMPLE1.CIR file self-contained.  These models
  167. *   come from the digital library files and would normally be accessed
  168. *   by using a .LIB command instead of reproducing them in the circuit
  169. *   file.
  170. .SUBCKT 74293 CKA CKB R01 R02 QA QB QC QD
  171. U1 NAND(2) R01 R02 RBAR D0_GATE IO_DFT
  172. U2 JKFF(1) $D_HI RBAR CKA $D_HI $D_HI QA $D_NC D_293ASTD IO_STD
  173. U3 JKFF(1) $D_HI RBAR CKB $D_HI $D_HI QB $D_NC D_293BSTD IO_STD
  174. U4 JKFF(1) $D_HI RBAR QB  $D_HI $D_HI QC $D_NC D_293BSTD IO_STD
  175. U5 JKFF(1) $D_HI RBAR QC  $D_HI $D_HI QD $D_NC D_293BSTD IO_STD
  176. .ENDS
  177.  
  178. .MODEL D0_GATE UGATE
  179. .MODEL IO_DFT  UIO (DRVH=50 DRVL=50 AtoD=STDATOD DtoA=STDDTOA)
  180. .MODEL IO_STD  UIO (DRVH=60 DRVL=30 AtoD=STDATOD DtoA=STDDTOA)
  181.  
  182. .MODEL D_293ASTD UEFF (
  183. + TPPCQHLTY   = 26ns TPPCQHLMX   = 40ns
  184. + TPCLKQLHTY  = 10ns TPCLKQLHMX  = 16ns
  185. + TPCLKQHLTY  = 12ns TPCLKQHLMX  = 18ns
  186. + TWCLKHMN    = 15ns TWCLKHTY    = 15ns TWCLKHMX    = 15ns
  187. + TWCLKLMN    = 15ns TWCLKLTY    = 15ns TWCLKLMX    = 15ns
  188. + TSUPCCLKHMN = 25ns TSUPCCLKHTY = 25ns TSUPCCLKHMX = 25ns
  189. + TWPCLTY     = 15ns TWPCLMX     = 15ns )
  190.  
  191. .MODEL D_293BSTD UEFF (
  192. + TPPCQHLTY   = 26ns TPPCQHLMX   = 40ns
  193. + TPCLKQLHTY  = 10ns TPCLKQLHMX  = 16ns
  194. + TPCLKQHLTY  = 14ns TPCLKQHLMX  = 21ns
  195. + TWCLKHMN    = 30ns TWCLKHTY    = 30ns TWCLKHMX    = 30ns
  196. + TWCLKLMN    = 30ns TWCLKLTY    = 30ns TWCLKLMX    = 30ns
  197. + TSUPCCLKHMN = 25ns TSUPCCLKHTY = 25ns TSUPCCLKHMX = 25ns
  198. + TWPCLTY     = 15ns TWPCLMX     = 15ns )
  199.  
  200. *
  201. * The digital power supply subckt:
  202. *  one instance of this subcircuit is created if any AtoD or DtoA
  203. *  subckts are created.  The one interface pin is always given the 
  204. *  value "0".
  205. .subckt    digifpwr gnd
  206. vdigpos $G_dig_pos $G_dig_neg 5v
  207. r1      $G_dig_pos gnd   1MEG
  208. vdigneg $G_dig_neg gnd   0v
  209. r2      $G_dig_neg gnd   1MEG
  210. vdigref $G_dig_ref gnd   0v
  211. r3      $G_dig_ref gnd   1MEG
  212. .ends
  213.  
  214. .model stmiomdl UIO (drvh=0 drvl=0 AtoD=STDATOD DtoA=STDDTOA)
  215.  
  216. * Simple AtoD and DtoA subckts: use globals to connect to power supply
  217. .subckt stdAtoD a d
  218. o1 a $G_dig_ref DOTTLSCH Dgtlnet = d  IO_STD
  219. .ends
  220.  
  221. .subckt stdDtoA d a
  222. n1 a $G_dig_neg $G_dig_pos DIN74 dgtlnet = d  IO_STD
  223. .ends
  224.  
  225. .model DIN74 dinput(
  226. +    s0name = 0, s0tsw = 5ns, s0rlo = 8.54 s0rhi = 238.9,
  227. +    s1name = 1, s1tsw = 8ns, s1rlo = 486  s1rhi = 209,
  228. +    s2name = X, s2tsw = 4ns, s2rlo = 64.4 s2rhi = 90.1,
  229. +    s3name = Z, s3tsw = 8ns, s3rlo = 100k s3rhi = 100k)
  230.  
  231. .model DOTTLSCH doutput(
  232. +    s0name = 0, s0vlo = -1.5, s0vhi = 1.4,
  233. +    s1name = 1, s1vlo = 1.40, s1vhi = 7.0)
  234.  
  235. .END
  236.